<talentTree value="503501523201322531025012511400200000000000000000000050000000000000000000000000"/>

    Public Sub Talents(ByVal strClass As String)
        ' Gather the source code
        Dim lstSource As New List(Of String)
        lstSource.Add("var jsLoaded; var document; var pointsTier = new Array(); var templateString; var reqTalentID; var reqTalentPoints; var variableIsSite; var maxRank; var theUpdatedRank; var showTip; var hideTip; var textNextRank; var textPoint; var textPoints;")
        Using wcClient As New System.Net.WebClient
            lstSource.Add(wcClient.DownloadString("http://www.wowarmory.com/shared/global/talents/includes/variables-live.js"))
            lstSource.Add(wcClient.DownloadString("http://www.wowarmory.com/shared/global/talents/includes/functions.js"))
            lstSource.Add(wcClient.DownloadString(String.Format("http://www.wowarmory.com/shared/global/talents/{0}/data.js", strClass.ToLower.Replace(" ", ""))))
            lstSource.Add(wcClient.DownloadString(String.Format("http://www.wowarmory.com/shared/global/talents/{0}/donotlocalize.js", strClass.ToLower.Replace(" ", ""))))
        End Using

        ' Compile the code
        Dim cdpProvider As CodeDomProvider = CodeDomProvider.CreateProvider("JScript")
        Dim cpParams As New CompilerParameters()
        cpParams.GenerateInMemory = True
        cpParams.GenerateExecutable = True
        Dim crResults As CompilerResults = cdpProvider.CompileAssemblyFromSource(cpParams, lstSource.ToArray())

        ' Run the main module of the assembly
        Dim lstArgs = New List(Of Object)
        lstArgs.Add(Nothing)
        Dim objReturn As Object = crResults.CompiledAssembly.EntryPoint.Invoke(Nothing, BindingFlags.Static, Nothing, lstArgs.ToArray(), Nothing)

        ' Get the type in the assembly that contains the data we want
        Dim tType As Type = (From t In crResults.CompiledAssembly.GetTypes() Where t.Name = "JScript 0").First()

        ' Get the tree names
        Dim fiTrees As FieldInfo = (From f In tType.GetFields() Where f.Name = "tree").First()
        Dim lstTrees As List(Of Object) = CType(Unbox(fiTrees.GetValue(Nothing)), List(Of Object))

        ' Get the talents
        Dim fiTalents As FieldInfo = (From f In tType.GetFields() Where f.Name = "talent").First()
        Dim lstTalents As List(Of Object) = CType(Unbox(fiTalents.GetValue(Nothing)), List(Of Object))

        ' Get the rank descriptions (some of these are in HTML format)
        Dim fiRanks As FieldInfo = (From f In tType.GetFields() Where f.Name = "rank").First()
        Dim lstRanks As List(Of Object) = CType(Unbox(fiRanks.GetValue(Nothing)), List(Of Object))

        ' Get the non localizable tree names... used to mine images like so:
        ' String.Format("http://www.wowarmory.com/shared/global/talents/{0}/images/armory/{1}/background.jpg", strClass.ToLower().Replace(" ", ""), strTree.ToLower().Replace(" ", ""))
        Dim fiNLTrees As FieldInfo = (From f In tType.GetFields() Where f.Name = "nltree").First()
        Dim lstNLTrees As List(Of Object) = CType(Unbox(fiNLTrees.GetValue(Nothing)), List(Of Object))

        ' Get the non localizable talents... used to mine images like so:
        ' String.Format("http://www.wowarmory.com/shared/global/talents/{0}/images/armory/{1}/{2}.jpg", strClass.ToLower().Replace(" ", ""), strTree.ToLower().Replace(" ", ""), strTalent.ToLower().Replace(" ", ""))
        ' String.Format("http://www.wowarmory.com/shared/global/talents/{0}/images/armory/{1}/{2}-off.jpg", strClass.ToLower().Replace(" ", ""), strTree.ToLower().Replace(" ", ""), strTalent.ToLower().Replace(" ", "").Replace(":", ""))
        Dim fiNLTalents As FieldInfo = (From f In tType.GetFields() Where f.Name = "nltalent").First()
        Dim lstNLTalents As List(Of Object) = CType(Unbox(fiNLTalents.GetValue(Nothing)), List(Of Object))

        ' TODO: Cache lists here for future use
    End Sub

    Private Function Unbox(ByVal obj As Object) As Object
        If TypeOf obj Is ArrayObject Then
            Dim aoObj = CType(obj, ArrayObject)
            If CInt(aoObj.length) = 0 Then
                Return New List(Of Object)
            Else
                Dim arr As Array = CType(Microsoft.JScript.Convert.ToNativeArray(aoObj, Type.GetTypeHandle(New Object)), Array)
                Dim lstReturn As New List(Of Object)
                For Each o As Object In arr
                    lstReturn.Add(Unbox(o))
                Next
                Return lstReturn
            End If
        Else
            Return obj
        End If
    End Function